Attribute Reference

The following pages list the attributes that are built into BullScript. Attributes are used to provide additional information about how your BullScript should be applied.

Attributes

Using Attributes

BullScript allow you to specify the way you want the results of a script to be displayed within the script itself, using its attributes system.

Attributes are defined within square brackets, “[” and “]”, and appear before the plots that they relate to. They consist of the name of the attribute being used, followed by an “=”, followed by the value of the attribute.

For instance, if you wanted to plot a 28-day simple moving average and a 14- day simple moving average, but you wanted the 28-day moving average to be displayed in green, and the 14-day moving average to be displayed in red, you could use the following code:

[color=green]
ma(C,28,SIMPLE);
[color=red]
ma(C,14,SIMPLE);


If a plot has more than one attribute, the attributes may be seperated by semicolons, or placed in separate sets of square brackets. For example, if you wanted to plot a 14-day moving average in red, on a new pane, you could use,

[color=red;
target=price]
ma(C,14,SIMPLE);


or

[color=red]
[target=price]
ma(C,14,SIMPLE);


Some attributes, such as author and category may take multiple values. All values must be given in the same attribute, and must be separated by pipes. See the table below for details.

[category=Moving Average|Verticality]
ma(C,14,SIMPLE);


Available Attributes

Color Attribute

Usage

[color=named-color]
[color=rgb(red,green,blue)]

Description

Specifies the colour for the following plot or ribbon component. You can either specify one of the named-colours listed below, or you can specify a colour exactly using the RGB notation.

Colour names are case insensitive and space insensitive. That is, you can remove the spaces from colour names and they will work as expected.

Note the American spelling of the color attribute. In general, BullScript uses American spelling for keywords as this is standard in most computer languages.

Example

[color=Red]
[color=AliceBlue]
[color=aliceblue]
[color=”Alice Blue”]
[color=rgb(0,128,255)]

Named Colors

See Also

Attributes

FillStyle Attribute

Usage

[fillstyle=style-name]

Description

Specifies the fill style to be used on the ribbon backgound.

Example

[fillstyle=SmallConfetti]

Fill Style Names

Backward Diagonal Dark Downward Diagonal   Dark Horizontal  Dark Upward Diagonal  Dark Vertical  Dashed Downward Diagonal  Dashed Horizontal Dashed Upward Diagonal  Dashed Vertical Diagonal Brick Diagonal Cross  Divot  Dotted Diamond  Dotted Grid  Forward Diagonal Horizontal  Horizontal Brick Large Checker Board  Large Confetti Large Grid  Light Downward Diagonal Light Horizontal Light Upward Diagonal Light Vertical Narrow Horizontal  Narrow Vertical Outlined Diamond

Percent 05   Percent 10  Percent 20  Percent 25  Percent 30  Percent 40 Percent 50   Percent 60  Percent 70 Percent 75 Percent 80 Percent 90 Plaid Shingle Small Checker Board  Small Confetti Small Grid Solid Solid Diamond Sphere Trellis Vertical Wave Weave  Wide Downward Diagonal Wide Upward Diagonal Zig Zag

See Also

Attributes

LineStyle Attribute

Usage

[linestyle=style-name]

Description

The linestyle attribute describes how the following calculations will be display. Most of the possible line styles change the formatting of a normal plot line.

There are several special formats available, some of which apply to results in pairs. See below for a detailed example of using various linestyles.

Normal LineStyle values

Special LineStyle values

Example 1 – Fills and Markers

This chart can be created using the script shown below. It is a modified version of the built-in “Moving Average – Crossover” indicator. The script demonstrates the Dash, Fill and Marker line styles.

[target=Price] [name=Short MA]
shortMA := ma(Close,5,simple);
shortMA;
[name=Long MA; linestyle=Dash]
longMA := ma(Close,13,simple);
longMA;

{ Fill } { Note that fill is green when shortMA is above longMA. } [linestyle=Fill] [color=shortMA] res1;
[color=longMA] res2;

{ Markers } { The name attribute automatically gets shown as a label. } { Use ‘tooltip’ to display a message when you hover over the marker. } [name=Above; linestyle=marker; marker=Long] [tooltip=”Short MA passed above Long MA”] cross(shortMA,longMA);

[name=Below; linestyle=marker; marker=Short] [tooltip=“Short MA passed below Long MA”] cross(longMA,shortMA);

Example 2 – Generating Text

Text can be generated and placed on the chart. The script below generates text for peaks and troughs of the zigzag function. Note that each text element is followed by two expressions. The first one determines the text to be shown, or undefined if no text is to be shown, and the second one indicates at what price level the text should be drawn. Combining the price level with the textalign attribute, the ‘peak’ label is drawn Above the High price.

[target=Price]
size := input(“Zig zag size“,4,0);
z := zigzag(Close,size,%);
ispeak := z>hist(z,1) and z>future(z,1);
istrough := z<hist(z,1) and z<future(z,1);

[linestyle=Solid; color=Red]
z;

[color=Blue] [linestyle=Text; textalign=Above,Center] if (isPeak, “Peak at ” + z, undefined);
High;

[linestyle=Text; textalign=Below,Center] if (isTrough, “Trough at ” + z, undefined);
Low;

See Also

Attributes

Ribbons

Usage

[target=Ribbon]

Description

A ribbon is displayed as a thick coloured bar at the bottom of the chart. The ribbon show different colours, or modes, to represent the current condition of the stock being analyzed.

To create a ribbon, first use the [target=Ribbon] attribute. Then define several calculations that evaluate to true or false, similar to the way markers work. Each result is evaluated in turn from top to bottom. The first calculation that is true is selected as the ribbon mode for the current bar.

Typically a name, colour and fillstyle attribute is given for each ribbon mode, and is defined before the calculation they relate to. A final colour can also be specified at the end of the indicator. This will be used if no conditions are matched.

Example

In this example, a green bar labelled ‘Rising’ will be shown when the 12 day moving average is above the 26 day moving average. A red bar labelled ‘Falling’ will be shown when the 12 day moving average is below the 26 day moving average.

[target=Ribbon]
[color=LightGreen; name=Rising]
[fillstyle=small grid]
MA(C,12,S)>MA(C,26,S);

[color=Pink; name=Falling]
[fillstyle=diagonal cross]
MA(C,12,S)<MA(C,26,S);

[color=White]

Results:

See Also

Attributes | Target attribute

Target Attribute

Usage

[target=target-type]

Description

Specifies the pane and/or axis that the indicator should appear on by default. Note that this can be overridden when the indicator is inserted.

BullCharts also has an option in the preferences to control how any indicator marked as target=default should be treated. It is recommended that newaxis, newpane and overlay not be used in light of this preference.

Presently only one target can be applied per script, however this may be revised in future versions of BullCharts.

Example

[target=Price]
ma(C,10,S) * 1.1;
ma(C,10,S) * 0.9;

Accepted Target Types

See Also

Attributes | LineStyle | Ribbons

TextFormat Attribute

Usage

[textformat=format-string]

Description

The textformat attribute is similar to the dp attribute in that it controls how data is formatted as text. However, it is much more flexible than the dp attribute. The textformat takes a .Net format string and can be used to apply a variety of formats to either numbers or dates.

If [textformat=default] is used the textformat will be switched off. The textformat attributes overrides the dp attribute. Therefore if textformat has been used in a script, then [textformat=default] should be used later if you want to start using the dp attribute again.

The textformat attribute currently only affects the formatting of BullScan column results.

This feature is recommended only for use by people who have prior programming experience.

Examples

[textformat=00 00 00 00] will make the number 12345678 appear as 12 34 56 78
[textformat=E] will make numbers appear in scientific (exponential) notation
[textformat=##;(##)] will show negative numbers in brackets

Format Strings

Documentation of the allowable format strings are beyond the scope of this manual. However, information is available from the Microsoft .Net online help. Click on the following links for details about format strings:

• Description and examples of basic numeric formats
• Description and examples of advanced numeric formats
• Description and examples of basic date formats
• Description and examples of advanced date formats

See Also

Attributes